# Maintainer: Sol Bekic <s+aur at s-ol dot nu>

_rockname=alive
pkgbase=lua-$_rockname
pkgname=("lua-$_rockname" "lua54-$_rockname" "lua53-$_rockname" "lua52-$_rockname" "lua51-$_rockname")
pkgver=0.2.r27.g6e9c1fc
pkgrel=1
pkgdesc='Open Sound Control (OSC) for lua/luajit'
arch=(any)
url="https://github.com/davidgranstrom/losc"
license=(MIT)
makedepends=(lua
             lua51
             lua52
             lua53
             lua54
             luarocks)
source=("git+https://git.s-ol.nu/alive.git")
sha256sums=('SKIP')

_package() {
	cd "$srcdir/alive"
	luarocks --lua-version="$1" --tree="$pkgdir/usr/" \
		make --deps-mode=none --no-manifest "dist/rocks/$_rockname"-scm-*.rockspec
	if [[ $pkgname != lua-$_rockname ]]; then
		rm -rf "$pkgdir/usr/bin"
	else
		find "$pkgdir/usr/bin" -type f -execdir sed -i -e "s#$pkgdir##g" {} \;
	fi

	depends=($2 $2-moonscript $2-lpeg $2-filesystem $2-system $2-socket)
	optdepends=($2-losc $2-rtmidi love $2-fltk4lua)
}

pkgver() {
	cd "$srcdir/alive"
	git describe --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

package_lua-alive() {
	_package 5.5 lua
}

package_lua51-alive() {
	_package 5.1 lua51
}

package_lua52-alive() {
	_package 5.2 lua52
}

package_lua53-alive() {
	_package 5.3 lua53
}

package_lua54-alive() {
	_package 5.4 lua
	optdepends+=('wxlua')
}