initial commit

1 files changed, 55 insertions, 0 deletions

diff --git a/lua-alive-git/PKGBUILD b/lua-alive-git/PKGBUILD
new file mode 100644
index 0000000..4b98fe7
--- /dev/null
+++ b/lua-alive-git/PKGBUILD
@@ -0,0 +1,55 @@
+# Maintainer: Sol Bekic <s+aur at s-ol dot nu>
+
+_rockname=alive
+pkgbase=lua-$_rockname
+pkgname=("lua-$_rockname" "lua53-$_rockname" "lua52-$_rockname" "lua51-$_rockname")
+pkgver=0.1.r199.gbe796c2
+_rockrel=10
+pkgrel=1
+pkgdesc='Open Sound Control (OSC) for lua/luajit'
+arch=(any)
+url="https://github.com/davidgranstrom/losc"
+license=(MIT)
+makedepends=(lua
+             lua51
+             lua52
+             lua53
+             luarocks)
+source=("git+https://git.s-ol.nu/alive.git")
+sha256sums=('SKIP')
+
+_package() {
+	cd "$srcdir/alive"
+	luarocks --lua-version="$1" --tree="$pkgdir/usr/" \
+		make --deps-mode=none --no-manifest "dist/rocks/$_rockname-scm-$_rockrel.rockspec"
+	if [[ $pkgname != lua-$_rockname ]]; then
+		rm -rf "$pkgdir/usr/bin"
+	else
+		find "$pkgdir/usr/bin" -type f -execdir sed -i -e "s#$pkgdir##g" {} \;
+	fi
+
+	depends=($2 $2-moonscript $2-lpeg $2-filesystem $2-system $2-socket)
+	optdepends=($2-losc $2-rtmidi love $2-fltk4lua)
+}
+
+pkgver() {
+	cd "$srcdir/alive"
+	git describe --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+package_lua-alive() {
+	_package 5.4 lua
+	optdepends+=('wxlua')
+}
+
+package_lua51-alive() {
+	_package 5.1 lua51
+}
+
+package_lua52-alive() {
+	_package 5.2 lua52
+}
+
+package_lua53-alive() {
+	_package 5.3 lua53
+}